| Server IP : 134.29.175.74 / Your IP : 216.73.216.160 Web Server : nginx/1.10.2 System : Windows NT CST-WEBSERVER 10.0 build 19045 (Windows 10) i586 User : Administrator ( 0) PHP Version : 7.1.0 Disable Function : NONE MySQL : OFF | cURL : ON | WGET : OFF | Perl : OFF | Python : OFF | Sudo : OFF | Pkexec : OFF Directory : /nginx/html/JimMartinson/_Archive/CST1861/Lab04/ooga/ |
Upload File : |
@echo off
:: now.cmd
:: Written by: Jim Martinson
:: Written on: 2010/03/19
setlocal enableextensions
:: Display help when the /? parameter is passed.
if NOT "%~1"=="/?" goto SkipHelp
echo Save the current day and date to environment variables.
echo.
echo Usage: %~n0
echo.
echo Save the following day and date information to environment variables:
echo _d = Day date (may be single digit).
echo _dd = Two digit day date.
echo _o = Month (may be single digit).
echo _mo = Two digit month.
echo _mon = Three letter month abbreviation (Jan, Feb, etc.).
echo _month = Full name of month (January, February, etc.).
echo _n = Weekday number (Sunday = 0).
echo _w = Single letter weekday abbreviation (UMTWHRFS).
echo _day = Three letter weekday abbreviation (Mon, Tue, etc.).
echo _weekday = Full weekday name (Monday, Tuesday, etc.).
echo _yy = Two digit year.
echo _yyyy = Four digit year.
echo _h = hour (may be single digit).
echo _h24 = hour in 24 hour format.
echo _hh = Two digit hour.
echo _m = minute (may be single digit).
echo _mm = Two digit minute.
echo _s = second (may be single digit).
echo _ss = Two digit second.
echo _la = a if AM, p if PM (a or p).
echo _ua = A if AM, P if PM (A or P).
echo _lam = am if AM, pm if PM (am or pm).
echo _uam = AM if AM, PM if PM (AM or PM).
echo.
goto:EOF
:SkipHelp
for /f "tokens=1-4 delims=/ " %%d in ('date /t') do call:DateInfo %%d %%e %%f %%g
for /f "tokens=1-3 delims=: " %%t in ('time /t') do call:TimeInfo %%t %%u %%v
for /f "tokens=5,7 delims=:. " %%s in ('echo.^|time^|find "is"') do call:TimeSeconds %%s %%t
(
endlocal
set _d=%_d%
set _dd=%_dd%
set _o=%_o%
set _mo=%_mo%
set _mon=%_mon%
set _month=%_month%
set _n=%_n%
set _w=%_w%
set _day=%_day%
set _weekday=%_weekday%
set _yy=%_yy%
set _yyyy=%_yyyy%
set _h=%_h%
set _hh=%_hh%
set _h24=%_h24%
set _m=%_m%
set _mm=%_mm%
set _s=%_s%
set _ss=%_ss%
set _la=%_la%
set _ua=%_ua%
set _lam=%_lam%
set _uam=%_uam%
)
goto:EOF
:DateInfo
set _day=%1
call:weekday%_day%
set _mo=%2
if %_mo:~0,1%==0 (set _o=%_mo:~1%) else (set _o=%_mo%)
call:month%_mo%
set _dd=%3
if %_dd:~0,1%==0 (set _d=%_dd:~1%) else (set _d=%_dd%)
set _yyyy=%4
set _yy=%_yyyy:~2%
goto:EOF
:TimeInfo
set _hh=%1
if %_hh:~0,1%==0 (set _h=%_hh:~1%) else (set _h=%_hh%)
set _mm=%2
if %_mm:~0,1%==0 (set _m=%_mm:~1%) else (set _m=%_mm%)
set _uam=%3
if %_uam%==AM (
set _la=a
set _ua=A
set _lam=am
) else (
set _la=p
set _ua=P
set _lam=pm
)
goto:EOF
:TimeSeconds
set _h24=%1
set _ss=%2
if %_ss:~0,1%==0 (set _s=%_ss:~1%) else (set _s=%_ss%)
goto:EOF
:month01
set _mon=Jan
set _month=January
goto:EOF
:month02
set _mon=Feb
set _month=February
goto:EOF
:month03
set _mon=Mar
set _month=March
goto:EOF
:month04
set _mon=Apr
set _month=April
goto:EOF
:month05
set _mon=May
set _month=May
goto:EOF
:month06
set _mon=Jun
set _month=June
goto:EOF
:month07
set _mon=Jul
set _month=July
goto:EOF
:month08
set _mon=Aug
set _month=August
goto:EOF
:month09
set _mon=Sep
set _month=Septemter
goto:EOF
:month10
set _mon=Oct
set _month=October
goto:EOF
:month11
set _mon=Nov
set _month=November
goto:EOF
:month12
set _mon=Dec
set _month=December
goto:EOF
:weekdayMon
set _n=1
set _w=M
set _weekday=Monday
goto:EOF
:weekdayTue
set _n=2
set _w=T
set _weekday=Tuesday
goto:EOF
:weekdayWed
set _n=3
set _w=W
set _weekday=Wednesday
goto:EOF
:weekdayThu
set _n=4
set _w=H
set _weekday=Thursday
goto:EOF
:weekdayFri
set _n=5
set _w=F
set _weekday=Friday
goto:EOF
:weekdaySat
set _n=6
set _w=S
set _weekday=Saturday
goto:EOF
:weekdaySun
set _n=0
set _w=U
set _weekday=Sunday
goto:EOF