| Server IP : 134.29.175.74 / Your IP : 216.73.216.160 Web Server : nginx/1.10.2 System : Windows NT CST-WEBSERVER 10.0 build 19045 (Windows 10) i586 User : Administrator ( 0) PHP Version : 7.1.0 Disable Function : NONE MySQL : OFF | cURL : ON | WGET : OFF | Perl : OFF | Python : OFF | Sudo : OFF | Pkexec : OFF Directory : C:/nginx/html/JimMartinson/_Archive/CST1861/CST1861/Lab04/ooga/ |
Upload File : |
@echo off
:: currentdriveused.cmd
:: Written by: Jim Martinson
:: Written on: yyyy/mm/dd
setlocal enableextensions
:: Display help when the /? parameter is passed.
if NOT "%~1"=="/?" goto SkipHelp
echo Show used space on current drive.
echo.
echo Usage: %~n0
echo.
goto:EOF
:SkipHelp
::D:\CST1861>fsutil volume diskfree d:
::Total # of free bytes : 7438262272
::Total # of bytes : 8586784768
::Total # of avail free bytes : 7438262272
:: Get the volume name for the current volume.
::for /f "tokens=4" %%v in ('dir^|find " Volume in drive"') do echo %%v
for /f "tokens=1 delims=\" %%v in ('cd') do set _volume=%%v
:: Get the free and total bytes of the volume.
for /f "tokens=4-7" %%a in ('fsutil volume diskfree %_volume%') do call:GetVolumeInfo %%a %%b %%c %%d
:: Trap errors for non-NTFS volumes.
if NOT defined _free (
echo %_volume% is not an NTFS volume.
echo Cannot calculate used space.
goto:EOF
)
set _freeOnes=%_free:~-9%
call:GetBillions %_free%
set _freeBillions=%_Billions%
set _sizeOnes=%_size:~-9%
call:GetBillions %_size%
set _sizeBillions=%_Billions%
:: Strip leading zeros.
call:stripZeros %_sizeOnes%
set _sizeOnes=%_stripZeros%
call:stripZeros %_freeOnes%
set _freeOnes=%_stripZeros%
set /a _usedOnes=_sizeOnes-_freeOnes
:: if negative add a billion and subtract 1 (or carry) from the billions
if %_usedOnes:~0,1%==- (
set /a _usedOnes = 1000000000+_usedOnes
set _carry=1
) else (
set _carry=0
)
set /a _usedBillions=_sizeBillions-_freeBillions-_carry
:: Normalize to base billion by adding left hand zeros
:addLeadingZeros
call:strLength %_usedOnes%
if NOT %_strLength%==9 (
set _usedOnes=0%_usedOnes%
goto:addLeadingZeros
)
set _used=%_usedBillions%%_usedOnes%
:: Strip leading zeros.
call:stripZeros %_used%
set _used=%_stripZeros%
:: Put in the thousands separators.
call:addCommas %_used%
echo %_addCommas% bytes used.
goto:EOF
:addComma
set _addCommas=,%_addCommas%
goto:EOF
:addCommas
call:strReverse %1
set #=%_strReverse%
set _addCommas=
set _addCommasCounter=1
:addCommasNextCharacter
if defined # (
set _addCommas=%#:~0,1%%_addCommas%
set #=%#:~1%
set /a _addCommasCounter+=1
if %_addCommasCounter%==3 (
call:addComma
set _addCommasCounter=1
)
goto:addCommasNextCharacter
)
goto:EOF
:GetBillions
call:strLength %1
set /a _BillionsLength=_strLength-9
set #=%1
set _Billions=
:GetBillionsNextBillionsNumber
if NOT "%_BillionsLength:~0,1%"=="-" if NOT %_BillionsLength%==0 (
set /a _BillionsLength-=1
set _Billions=%_Billions%%#:~0,1%
set #=%#:~1%
goto:GetBillionsNextBillionsNumber
)
if "%_Billions%"=="" set _Billions=0
goto:EOF
:GetVolumeInfo
if "%1"=="free" set _free=%4
if "%1"=="bytes" set _size=%3
goto:EOF
:strLength
set #=%1
set _strLength=0
:strLengthNextCharacter
if defined # (
set /a _strLength+=1
set #=%#:~1%
goto:strLengthNextCharacter
)
goto:EOF
:strReverse
set #=%1
set _strReverse=
:strReverseNextCharacter
if defined # (
set _strReverse=%#:~0,1%%_strReverse%
set #=%#:~1%
goto:strReverseNextCharacter
)
goto:EOF
:stripZeros
set _stripZeros=%1
:stripZerosNext
if "%_stripZeros:~0,1%"=="0" (
set _stripZeros=%_stripZeros:~1%
goto:stripZerosNext
)
if "%_stripZeros%"=="" set _stripZeros=0
goto:EOF