| Server IP : 134.29.175.74 / Your IP : 216.73.216.160 Web Server : nginx/1.10.2 System : Windows NT CST-WEBSERVER 10.0 build 19045 (Windows 10) i586 User : Administrator ( 0) PHP Version : 7.1.0 Disable Function : NONE MySQL : OFF | cURL : ON | WGET : OFF | Perl : OFF | Python : OFF | Sudo : OFF | Pkexec : OFF Directory : C:/nginx/html/JimMartinson/_Archive/CST1861/ExampleFiles/Lab04/ |
Upload File : |
@echo off
:: @Backup.cmd
:: Written by:
:: Written on:
:: Test if command line extensions are enabled.
if "%~1"=="~1" goto:ExtensionsAreNotEnabled
:: Display help when the /? parameter is passed.
if NOT "%~1"=="/?" goto SkipHelp
:Help
echo Backup all directories that begin with an '@' from the
echo source_drive to the destination_drive.
echo.
echo Usage: %~n0 [source_drive [destination_drive]]
echo.
echo source_drive = The drive to backup.
echo Default is C:
echo destination_drive = The destination drive to receive the backup.
echo Default is to prompt for the destination_drive.
goto:EOF
:ExtensionsAreNotEnabled
echo Command line extensions are not enabled. They must be enabled for %~n0 to work properly.
echo %~n0 aborted.
echo.
goto:Help
:SkipHelp
:: Get source_drive from the command line.
set _source_drive=%~1
if NOT defined _source_drive set _source_drive=C:
:: Verify _source_drive is a drive.
if /i "%_source_drive:~0,1%" GEQ "A" if /i "%_source_drive:~0,1%" LEQ "Z" if "%_source_drive:~1%" EQU ":" goto:source_driveValid
echo The source drive is not a valid volume name.
goto:EOF
:source_driveValid
:: Get destination_drive from the command line.
set _destination_drive=%~2
:destination_driveAsk
if NOT defined _destination_drive (
set /P _destination_drive=Enter destination drive and hit enter:
goto:destination_driveAsk
)
:: Verify _destination_drive is a drive.
if /i "%_destination_drive:~0,1%" GEQ "A" if /i "%_destination_drive:~0,1%" LEQ "Z" if "%_destination_drive:~1%" EQU ":" goto:destination_driveValid
echo The destination drive is not a valid volume name.
goto:EOF
:destination_driveValid
for /f "tokens=1,* delims=:" %%d in ('dir /s /ad /b %_source_drive%\@*') do (
xcopy /I "%_source_drive%%%e" "%_destination_drive%%%e"
)
goto:EOF
:backupDrive